Entrada 11 (Bloqueo por IP si usuario no existe en sp_Login y agregar sp_Logout)

   Fecha: 25/04/2026

Inicio: [22:38] | Fin: [23:14] || Total: [36 minutos]

Presentes: Sebastián Ramírez Abarca

━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
¿QUÉ HICIMOS HOY?
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
Se actualizó sp_Login de forma que si se ingresa usernames incorrectos 5 veces en 20 minutos desde una misma IP se bloqueará por IP.
Se avanzó con store procedures: se hizo sp_Logout.
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
PROBLEMAS ENCONTRADOS Y CÓMO SE RESOLVIERON
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
No hubo problemas puesto que el código agregado es sencillo.
Aclarar que no se ha probado el programa con estos cambios aún.
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
DUDAS Y DIVERGENCIAS DE CRITERIO
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
1. No surgió ninguna duda en esta sesión.
2. Debido a que en este sesión solo participó una persona no hubo divergencias.
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
AVANCE DEL CÓDIGO
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
código actualizado completo de sp_Login:

USE VacacionesDB;
GO

-- =====================================================
-- SP: Login de usuario
-- =====================================================
DROP PROCEDURE IF EXISTS sp_Login;
GO

CREATE PROCEDURE sp_Login
    @inUsername VARCHAR(128),
    @inPassword VARCHAR(128),
    @inIpPostIn VARCHAR(64),
    @inPostTime DATETIME,
    @outResultCode INT OUTPUT
AS
BEGIN

    SET NOCOUNT ON;

    DECLARE @idUsuario INT,
        @password VARCHAR(128),
        @idTipoEventoSuccess INT,
        @idTipoEventoFail INT,
        @idTipoEventoDisabled INT,
        @intentosFallidos INT,
        @descripcion VARCHAR(512)

        SET @outResultCode = 0;

    BEGIN TRY
           
        SELECT @idTipoEventoSuccess = t.id
        FROM dbo.TipoEvento t
        WHERE t.Nombre = 'Login Exitoso';

        SELECT @idTipoEventoFail = t.id
        FROM dbo.TipoEvento t
        WHERE t.Nombre = 'Login No Exitoso';

        SELECT @idTipoEventoDisabled = t.id
        FROM dbo.TipoEvento t
        WHERE t.Nombre = 'Login deshabilitado';

        -- Obtener datos del usuario
        -- @idUsuario y @password serán NULL si no existe @inUsername en la BD
        SELECT @idUsuario = u.id, @password = u.password
        FROM dbo.Usuario u
        WHERE u.Username = @inUsername;

        -- Verificar que existe usuario
        IF @idUsuario IS NULL
        BEGIN

            -- Contat intentos fallidos por IP en los ultimos 20 min
            SELECT @intentosFallidos = COUNT(*)
            FROM dbo.BitacoraEvento b
            WHERE b.idTipoEvento = @idTipoEventoFail
                AND b.IpPostIn = @inIpPostIn
                AND b.PostTime >= DATEADD(MINUTE, -20, @inPostTime);
           
            IF @intentosFallidos >= 5
            BEGIN
                SET @outResultCode = 50003;

                INSERT INTO dbo.BitacoraEvento (idTipoEvento, Descripcion, idUsuario, IpPostIn, PostTime)
                VALUES (@idTipoEventoDisabled, NULL, NULL, @inIpPostIn, @inPostTime)

                RETURN;
            END

            SET descripcion = 'Intento: ' + CAST(@intentosFallidos + 1 AS VARCHAR(10))
                + ' | Error: ' + (SELECT Descripcion FROM dbo.Error WHERE Codigo = 50001);

            INSERT INTO dbo.BitacoraEvento (idTipoEvento, Descripcion, idUsuario, IpPostIn, PostTime)
            VALUES (@idTipoEventoFail, @descripcion, NULL, @inIpPostIn, @inPostTime);

            SET @outResultCode = 50001;
            RETURN;
        END

        -- Contar intentos fallidos en los ultimos 20 min
        SELECT @intentosFallidos = COUNT(*)
        FROM dbo.BitacoraEvento b
        WHERE b.idTipoEvento = @idTipoEventoFail
            AND b.idUsuario = @idUsuario
            AND b.IpPostIn = @inIpPostIn
            AND b.PostTime >= DATEADD(MINUTE, -20, @inPostTime);

        IF @intentosFallidos >= 5
        BEGIN
            SET @outResultCode = 50003;

            INSERT INTO dbo.BitacoraEvento (idTipoEvento, Descripcion, idUsuario, IpPostIn, PostTime)
            VALUES (@idTipoEventoDisabled, NULL, @idUsuario, @inIpPostIn, @inPostTime)

            RETURN;
        END

        -- Verficar password
        IF @password <> @inPassword
        BEGIN
            SET @outResultCode = 50002;

            SET @descripcion = 'Intento: ' + CAST(@intentosFallidos + 1 AS VARCHAR(10))
                + ' | Error: ' + (SELECT Descripcion FROM dbo.Error WHERE Codigo = 50002);

            INSERT INTO dbo.BitacoraEvento (idTipoEvento, Descripcion, idUsuario, IpPostIn, PostTime)
            VALUES (@idTipoEventoFail, @descripcion, @idUsuario, @inIpPostIn, @inPostTime);

            RETURN;
        END

        -- Si Login exitoso
        INSERT INTO BitacoraEvento (idTipoEvento, Descripcion, idUsuario, IpPostIn, PostTime)
        VALUES (@idTipoEventoSuccess, 'Exitoso', @idUsuario, @inIpPostIn, @inPostTime);

        SET @outResultCode = 0;
       
    END TRY
    BEGIN CATCH
       
        INSERT INTO DBError (UserName, Number, State, Severity, Line, [Procedure], Message, DateTime)
        VALUES (
            SYSTEM_USER,
            ERROR_NUMBER(),
            CAST(ERROR_STATE()    AS VARCHAR(32)),
            CAST(ERROR_SEVERITY() AS VARCHAR(32)),
            ERROR_LINE(),
            ISNULL(ERROR_PROCEDURE(), 'sp_Login'),
            ERROR_MESSAGE(),
            GETDATE()
        );

        SET @outResultCode = 50008;

    END CATCH
END;
GO
sp_Logout:
USE VacacionesDB;
GO

-- =====================================================
-- SP: Logout de usuario
-- =====================================================

DROP PROCEDURE IF EXISTS sp_Logout;
GO

CREATE PROCEDURE sp_Logout
    @inIdUsuario INT,
    @inIpPostIn VARCHAR(64),
    @inPostTime DATETIME,
    @outResultCode INT OUTPUT
AS
BEGIN
    SET NOCOUNT ON

    DECLARE @idTipoEventoLogout INT;

    SET @outResultCode = 0;

    BEGIN TRY

        SELECT @idTipoEventoLogout = t.id
        FROM dbo.TipoEvento t
        WHERE t.Nombre = 'Logout';

        INSERT INTO dbo.BitacoraEvento (idTipoEvento,Descripcion, idUsuario, IpPostIn, PostTime)
        VALUES (@idTipoEventoLogout, NULL, @inIdUsuario, @inIpPostIn, @inPostTime)

        SET @outResultCode = 0;
   
    END TRY
    BEGIN CATCH

        INSERT INTO dbo.DBError (UserName, Number, State, Severity, Line, [Procedure], Message, DateTime)
        VALUES (
            SYSTEM_USER,
            ERROR_NUMBER(),
            CAST(ERROR_STATE() AS VARCHAR(32)),
            CAST(ERROR_SEVERITY() AS VARCHAR(32)),
            ERROR_LINE(),
            ISNULL(ERROR_PROCEDURE(), 'sp_Logout'),
            ERROR_MESSAGE(),
            GETDATE()
        );
       
        SET @outResultCode = 50008

    END CATCH
END;
GO
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
MORALEJAS / BUENAS PRÁCTICAS
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
1. Si se utiliza la configuración de autocompletar en Visual Studio Code al hacer commit se registrará que ese commit fue co-trabajado con Copilot.
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
PRÓXIMA SESIÓN: ¿QUÉ SIGUE?
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━
- Integrar sp_GetError a capa lógica.

Comentarios

Publicar un comentario

Entradas más populares de este blog

Entrada 16 (Controlador de movimientos)

Fecha: 27 de abril de 2026 Inicio: [11:34] | Fin: [12:48] || Total: [1 hora y 16 minutos] Presente: Sebastián Ramírez Abarca ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ ¿QUÉ HICIMOS HOY? ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - Se creó el archivo movimientoController.ts que controla movimientos. - Se creó el archivo movimientos.ts para manejar la ruta. - Se corrigió una dirección en errorHelper.ts   ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ PROBLEMAS DETECTADOS Y CÓMO RESOLVERLOS ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - En errorHelper.ts escribí mal una dirección por lo que daba error al probar con datos que debían tirar error. Solución: corregir la ruta, me faltó un punto para señalar que vaya a la dirección raíz. Antes: import { getPool, sql } from './db/connection'; Después: import { getPool, sql } from '../db/connection'; ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ DUDAS Y DIVERGENCIAS DE CRITERIOS ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - No hubo dudas ni divergencias en esta sesión.   ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ AVANCE...
Leer más

Entrada 20 (Lógica de insertarMovimientos, conectarla y probarla)

  Fecha: 28 y 30 de abril de 2026  Inicio: [1:39] | Fin: [2:24] U  Inicio: [2:48] | Fin: [3:59]  U Inicio: [11:27] | Fin: [12:08] Inicio: [13:10] | Fin: [14:36]  y Inicio: [9:21] | Fin: [10:04] (bitacora) || Total: [4 horas y 36 minutos] Presente: Sebastián Ramírez Abarca ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ ¿QUÉ HICIMOS HOY? ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - Se creó la página insertar movimiento con insertarMovimiento.html. - Se creó insertarMovimiento.ts para y se compiló para crear insertarMovimiento.js que maneja la página de insertarMovimiento, específicamente hace:      + Lee el ?documento=... de la URL para saber a qué empleado corresponde.      + Carga los datos del empleado llamando a /api/empleados/:doc y los muestra.      + Carga la dropdown list de tipos de movimiento llamando a /api/tiposMovimiento.      + Valida que el monto no deje el saldo negativo cuando el tipo de movimiento es...
Leer más

Entrada 21 (Análisis de resultados)

  Fecha: 30 de abril de 2026 Inicio: [11:04] | Fin: [12:30] || Total: [1 y 30 minutos] Presente: Sebastián Ramírez Abarca ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ ¿QUÉ HICIMOS HOY? ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - Se completó el documento de análisis de resultados.   ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ PROBLEMAS DETECTADOS Y CÓMO RESOLVERLOS ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - No hubo problemas, ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ DUDAS Y DIVERGENCIAS DE CRITERIOS ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - No hubo dudas ni divergencias en esta sesión.   ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ AVANCE DEL CÓDIGO ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━  No hubo avances de código pero si en el documento de análisis de resultados. https://docs.google.com/document/d/1opHiYGH0-cvMlYvdahf1ALpLYPmzwqVrkoZ3SrmLOYE/edit?usp=sharing ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ MORALEJAS / BUENAS PRÁCTICAS ━━━━━━━━━━━━━━━━━━━━━━━━━━━━━━ - Usamos como plantilla el documento que usamos para la tarea pasada pero implementando las correcciones hec...
Leer más